Natürliche Radioaktive Umgebungsstrahlung messen mit Arduino

Radioaktive Strahlung ist allgegenwärtig und jeder ist auf natürliche Weise dieser Strahlung ausgesetzt. In Deutschland ist je nach Standort die gesamte Strahlenbelastung zwischen ein bis zehn Millisievert pro Jahr. Sie kommt aus dem Boden, unseren Baumaterialien, der Nahrung, aus dem Weltall usw.
Hinzu kommen die technisch erzeugten ionisierenden Strahlungen zum Beispiel beim Röntgen.

Die Grenzwerte und weitere Informationen zum Strahlenschutz kann auf der Webseite des Bundesamt für Strahlenschutz (BfS) eingesehen werden.

https://www.bfs.de/DE/themen/ion/strahlenschutz/grenzwerte/grenzwerte.html

Zum Nachweis und zur Messung ionisierender Strahlung kommt unter anderem das Zählrohr des deutschen Physiker Hans Geiger zum Einsatz.

Radioaktive Teilchen bewirken die Ionisierung eines oder mehrerer Atome des Füllgases im Auslösezählrohr. Die anliegende Spannung ist so gewählt, dass es bei Ladungsträgern im Füllgas wie in einer Gasentladungsröhre zu einem plötzlichen Elektronenschub und einer Gasentladung kommt. Dadurch entsteht im Zählrohr ein Stromstoß, der durch Abgreifen eines externen Widerstandes in einen Spannungsimpuls umgewandelt wird. Das kann ohne Verstärkung direkt an einem Lautsprecher als Knackgeräusch hörbar gemacht werden. Danach erfolgt eine kurze Totzeit von etwa 0,1 Millisekunden.

Diese steigenden und fallenden Signale nutze ich nun, um mit einen Microcontroller diese Entladungen elektronisch zu zählen.
Mit einer Ausgabe der Werte auf einen kleinen OLED Display kann diese Lösung zu experimentellen Strahlenschutzzwecken bestimmt dienlich sein.

Das Geigerzähler Modul für Arduino

Das hier zu sehende Modul Radiationd-v1.1 wurde vormontiert mit einer Plexiglas-Abdeckung geliefert.
Das Zählrohr J305 war separat und sehr gut verpackt. Beim Einsetzen unbedingt auf die Polung achten.
Die Arbeitsspannung des Moduls liegt bei 5V.

Das Zählrohr wird durch dem auf der Platine vorhandenen 5V DC – 400V DC-Wandler
mit etwa 400V / 0,02A versorgt. Es ist also Vorsicht geboten.
Zum Schutz vor Berührung habe ich ein Gehäuse erstellt und bei Thingiverse zum Download bereitgestellt.
Zum Testen kann es auch ohne Microcontroller eingeschaltet werden. Es benötigt einige Sekunden, bis es anfängt aus dem verbauten Buzzer zu knacken und zeitgleich eine rote LED kurz aufflackert, die anzeigt, dass radioaktive Teilchen auf das Zählrohr treffen.

Kalibrierung:
Das Modul wird vorkalibriert geliefert.
Optional zum Einstellen und Kontrollieren, gibt es hier eine Anleitung

Zu erwartende Messdaten:

Der Hersteller des mitgelieferte Zählrohr J305 gibt an, das die Conversation Rate bei 153,8 liegt.
Soll heißen: 153,8 Treffer pro Minute (cpm) = 1 Mikrosievert pro Stunde Werte (µSv/h)

Für die Formel im Quellcode rechne ich lediglich 1:153,8 = 0.0065.
µSv/h = cpm * 0.0065

Quellcode:

#include <SPI.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

const int Interruptpin = 3;       // GPIO Anschluss des Zählrohr
const int durchlaufzeit = 12000;  // 12 Sekunden
unsigned long treffer;            // Gezählte Treffer des Zählrohr
unsigned long tpm;                // Treffer pro Minute

#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 64 // OLED display height, in pixels
#define OLED_RESET  -1
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

void setup(){
  treffer = 0;
  tpm = 0;
  pinMode(Interruptpin, INPUT);
  display.display();
  delay(2000);
  display.clearDisplay();
  display.begin(SSD1306_SWITCHCAPVCC, 0x3C); //I2C-Adresse des OLED ggf anpassen
  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(SSD1306_WHITE);
  display.setCursor(0, 0);  //Erster Wert = Anzahl Pixel von links, bis Schrift beginnt
                            // Zweiter Wert = Anzahl Pixel von oben, bis Schrift beginnt
  display.println("Strahlenschutzmessung ");
  display.setCursor(5, 35);
  display.println("Fange an zu zaehlen");
  display.display();
  
// immer wenn fallendes Signal am Geigerzähler soll Funktion counter_hit Zähler um 1 erhöhen
attachInterrupt(digitalPinToInterrupt(Interruptpin), counter_hit, FALLING);
}

void loop(){
  static unsigned long startzeit;
  unsigned long zeit = millis();//Millisekunden seit Auslöser
  double uSv; //Microsievert Wert pro Stunde

  //Wert errechnen beim Ende der Durchlaufzeit
  if (zeit - startzeit > durchlaufzeit) {
    startzeit = zeit;
    if (treffer) {
      tpm = treffer * 5; // Treffer pro Durchlauf mal Wert um auf eine Minute zu kommen
      uSv = tpm * 0.0065; // Zählrohr Konversationsrate J305: 153,8 CPM = 1 uSv/h 
    } else {
      uSv = 0;
    }
    display.display();
    display.clearDisplay();
    display.setTextSize(1);
    display.setTextColor(SSD1306_WHITE);
    display.setCursor(0, 0);
    display.println("Strahlenschutzmessung");
    display.setCursor(7, 17);
    display.println("Treffer:");
    display.setCursor(57, 17);
    display.println(treffer);
    display.setCursor(7, 30);
    display.println("pro Minute cpm:");
    display.setCursor(100, 30);
    display.println(tpm);
    display.setCursor(7, 43);
    display.println("uSv/h:");//Mikrosievert/h
    display.setCursor(50, 43);
    display.println(uSv,4);
    
// Check, ob Alles Ok oder ALARM
    if ( tpm > 90 ) {  // Dosis ueber Normalwert wenn >5mSv/a
      display.display();
      display.clearDisplay();
      display.setTextSize(1);
      display.setTextColor(SSD1306_WHITE);
      display.setCursor(7, 10);
      display.println("ALARM!");
      display.setCursor(7, 23);
      display.println("Dosis ueber Wert!");
      display.setCursor(7, 36);      
      display.println("cpm ist:");
      display.setCursor(55, 36);
      display.println(tpm);
      display.setCursor(8, 49);
      display.println(tpm-90);// ueber Normalwert wird hier abgezogen
      display.setCursor(25, 49);
      display.println("mehr als normal");
    } else {
      display.setCursor(7, 56);
      display.println("Alles ist OK !");
  }
  treffer = 0;
  tpm = 0;
}
delay(50);
}

void counter_hit() { 
  treffer++;          // bei Treffer plus 1 pro Durchlaufzeit
}

Für eine Kontrolle und einen Abgleich der Messdaten in der eigenen Umgebung bietet das Bundesamt für Strahlenschutz aktuelle Werte von über 1700 Standorten unter https://odlinfo.bfs.de

Hardware:

Module Radiationd-v1.1 mit Zählrohr
Arduino Uno
OLED Display I2C

Verdrahtung:

Nicht verwirren lassen: VIN ist bei diesem Board der Signalausgang des Impulszählers, trotz der irreführenden Beschriftung

Anbinden eines OLED Display über I2C:
https://prilchen.de/oled-display-i2c-bus/

Was kann verwendet werden, um das Gerät zu testen:

Hier sind einige gut zugängliche Testobjekte:

1. Pottasche (Kaliumcarbonat) oder Diätsalz Pottasche ist ein Backtriebmittel, das du im Supermarkt bei den Backzutaten kaufen kannst. Es enthält natürliches Kalium. Ein winziger Anteil davon ist das Isotop (eine bestimmte Atom-Variante) Kalium-40, welches schwach strahlt. Auch Diätsalz (Kaliumchlorid, kurz KCl) funktioniert. Hinweis: Die Strahlung ist sehr schwach. Das Zählrohr muss direkt an das Pulver gehalten werden, und man braucht etwas Geduld, um einen messbaren Unterschied zur normalen Umgebungsstrahlung zu erkennen.

2. Uranglas Dieses spezielle Glas wurde früher für Vasen, Schüsseln oder Gläser verwendet und ist oft leicht grünlich oder gelblich. Unter UV-Licht (Ultraviolett-Licht, also Schwarzlicht) leuchtet es stark neongrün. Man findet es häufig auf Flohmärkten. Es gibt eine gut messbare, aber harmlose Menge an Strahlung ab und ist eines der beliebtesten Testobjekte.

3. Alte Uhren und Wecker (mit Leuchtziffern) Armbanduhren, Taschenuhren oder Wecker, die vor 1960 hergestellt wurden, nutzen oft Radium-Leuchtfarbe für die Zeiger und Ziffern, damit sie im Dunkeln leuchten. Diese Uhren lassen das Messgerät meist sehr schnell und stark ausschlagen. Wichtig: Die Uhren dürfen niemals geöffnet werden! Die alte Farbe kann bröselig sein, und den entstehenden Staub darf man auf keinen Fall einatmen oder verschlucken.

4. Rote Wolframelektroden Beim WIG-Schweißen (Wolfram-Inertgas-Schweißen) wurden früher oft Elektroden verwendet, denen Thorium beigemischt wurde, um die Zündeigenschaften zu verbessern. Diese Elektroden sind an einer roten Farbmarkierung (Typ WT20) zu erkennen. Im Baumarkt gibt es heute meist nur noch strahlungsfreie Alternativen, aber im Fachhandel oder online sind sie noch zu finden.

5. Alte Glühstrümpfe für Gaslampen Glühstrümpfe, die man in alte Camping-Gaslampen einsetzt, wurden früher in eine Thorium-Lösung getaucht, um die Leuchtkraft zu erhöhen. Moderne Glühstrümpfe sind heute strahlungsfrei. Wenn man aber noch alte Bestände (sogenannte Thorium-Glühstrümpfe) findet, eignen sie sich hervorragend für einen Test.

6. Granitsteine Bestimmte Arten von Granit, wie man sie in alten Pflastersteinen, Küchenarbeitsplatten oder Fliesen findet, enthalten natürliche Spuren von Uran und Thorium. Auch hier muss das Gerät meist direkt auf den Stein gelegt werden, um nach ein paar Minuten einen Anstieg der Werte festzustellen.

Versuchsaufbau mit Pottasche

Um zu prüfen, ob der Eigenbau funktioniert, benötigen wir eine sichere, schwach strahlende Quelle. Hierfür eignet sich einfache Pottasche (Kaliumcarbonat), die man in jedem Supermarkt in der Backabteilung findet. Pottasche enthält von Natur aus einen winzigen Anteil des Isotops (eine bestimmte Atom-Variante) Kalium-40, welches leicht radioaktiv ist.

Die Durchführung:

1. Starte das Messgerät und warte ein bis zwei Durchläufe ab, um den normalen Wert deiner Umgebung zu sehen.
2. Halte das J305-Zählrohr direkt an oder auf die geöffnete Tüte mit der Pottasche.
3. Warte das Messintervall von 12 Sekunden ab.

Die Beobachtung: Du wirst feststellen, dass das Zählrohr deutlich öfter knackt. Die gemessenen Treffer steigen spürbar an. Bei einem Test stiegen die Werte auf 26 Treffer im 12-Sekunden-Intervall. Hochgerechnet sind das 130 „Counts per Minute“ (CPM / Zählimpulse pro Minute).

Der Lerneffekt (Warum der Mikrosievert-Wert nicht stimmt): Das Display zeigt bei 130 CPM nun einen Wert von rund 0,845 Mikrosievert pro Stunde (µSv/h) an. Dieser Wert wäre für die normale Hintergrundstrahlung sehr hoch. Die Backzutat ist aber völlig ungefährlich. Hier zeigt sich eine physikalische Besonderheit, die beim Messen extrem wichtig ist:

• Gammastrahlung vs. Betastrahlung: Der Umrechnungsfaktor in unserem Quellcode (153,8 CPM = 1 µSv/h) gilt nur für hochenergetische Gammastrahlung. Kalium-40 in der Pottasche ist aber ein sogenannter Betastrahler. Betastrahlung ist sehr schwach und wird oft schon von der Luft oder der obersten Hautschicht gestoppt.
• Der blinde Mikrocontroller: Die Betateilchen dringen durch die Hülle des Zählrohrs und lösen einen Zählimpuls (Treffer) aus. Der Mikrocontroller auf dem Entwicklungsboard registriert den Treffer, weiß aber nicht, dass es sich um harmlose Betastrahlung handelt. Er wirft den Treffer in unsere Formel und berechnet fälschlicherweise eine hohe Dosis an Gammastrahlung.

Ergebnis des Versuchs: Die Messung mit Pottasche beweist eindrucksvoll, dass unser selbstgebautes Modul einwandfrei funktioniert und selbst geringste Veränderungen der natürlichen Strahlung zuverlässig aufspürt. Es zeigt aber auch, dass die berechneten Mikrosievert-Werte bei solchen reinen Betastrahlern stark überhöht sind und nicht als echte Dosisleistung gewertet werden dürfen.

Fazit: Was das Gerät kann (und was nicht)

Zusammenfassend lässt sich sagen, dass der Aufbau mit dem J305-Zählrohr und dem Mikrocontroller (Arduino oder ESP32) wunderbar funktioniert, um das Prinzip der Strahlungsmessung praktisch zu begreifen. Unser Versuchsaufbau mit der Pottasche hat gezeigt, dass die Elektronik selbst geringste Mengen an natürlicher Betastrahlung zuverlässig aufspürt und auswertet.

Dennoch ist eine wichtige physikalische Einordnung nötig: Dieses Projekt dient ausdrücklich Ausbildungs- und Experimentierzwecken und ist eine anschauliche Annäherung.

• Keine amtliche Messung: Das Zählrohr ist quasi „blind“ für die Art der Strahlung. Es registriert jeden Treffer, ob energiereicher Gammastrahl oder schwacher Betastrahl, erzeugt den gleichen elektrischen Impuls.
• Theoretischer Umrechnungsfaktor: Die im Code verwendete Konversationsrate (153,8 CPM = 1 µSv/h) ist ein vom Hersteller angegebener Durchschnittswert, der nur für Gammastrahlung gilt. Halten wir das Gerät an einen Betastrahler wie Pottasche, registriert es zwar die hohe Anzahl der Treffer (CPM), die hinterlegte Formel errechnet daraus jedoch fälschlicherweise eine viel zu hohe Sievert-Dosis.
• Einsatzzweck: Bei gemischten Strahlern oder Betastrahlern ist der angezeigte CPM-Wert (Zählimpulse pro Minute) der entscheidende Indikator, um zu sehen: „Hier strahlt etwas.“ Wer verlässliche Dosisleistungen in Mikrosievert zur persönlichen Sicherheit benötigt, muss zwingend auf ein professionell geeichtes Messgerät zurückgreifen.

Wer jedoch die Grundlagen der Ionisierung verstehen, Programmabläufe testen und einen ausbaufähigen Sensor in seine eigenen Code-Projekte integrieren möchte, hat hiermit eine hervorragende und funktionale Basis geschaffen.

Youtube-Video:

Optional nicht im Video zu sehen:

Neuer Aufbau mit einem deutlich kleineren Nano Board mit unveränderter Verdrahtung, das von einer kleinen USB-Powerbank mit Spannung versorgt wird.
Um mal zu schauen wie hoch der Stromverbrauch bei dieser Lösung ist, schließlich versorgt das Board das Zählrohr und das OLED Display gleich mit, ist hier optional auch ein Spannungsprüfer zwischen gesteckt.